Bequem umfangreiche doppelseitige Papiervorlagen in PDF umwandeln

Längere einseitige Dokumente lassen sich ja dank automatischer Dokumenteneinzüge bei einigen Scannern oder Multifunktionsgeräten (z.B. der Canon Pixma MP 750) ja schon problemlos einscannen, und mit der mitgelieferten Software in ein PDF umwandeln. Wenn die Vorlage allerdings doppelseitig beschrieben/bedruckt ist, dann benötigt man entweder einen teuren Scanner der Duplex scannen kann, oder behilft sich mit etwas Software und ein Skript.

Scannen

Zuerst scannt man alle Vorderseiten, und speichert sie in einem Ordner ab, so das sie der Seitenzahlen nach aufsteigend sortiert sind. Dies kann durch einen laufenden Index geschehen, oder indem man als Scanprogramm „Digitale Bilder“ und den TWAIN-Treiber des Scanners nutzt, da dieses die Dateien nach Datum und Uhrzeit nummeriert abspeichert.

Die Rückseiten scannt man danach, indem man den Stapel umdreht, und ihn einscannt. Wieder werden die Dateien in einen Ordner gespeichert (einen anderen als die Vorderseiten) und in der Scanreihenfolge aufsteigend benannt.

Sortierung

Nachdem alle Seiten als Bilddatei nun vorliegen, müssen diese in die richtige Reihenfolge gebracht werden.
Dazu kann man das folgende AppleScript nutzen:

set the vorderseiten_folder to (choose folder with prompt "Wähle den Ordner mit den Vorderseiten aus:")
set the rueckseiten_folder to (choose folder with prompt "Wähle den Ordner mit den Rückseiten aus:")
set the ziel_folder to (choose folder with prompt "Wähle den Zielordnern aus:")

set the prefix_or_suffix to ""
repeat
    display dialog "Geben sie die Dateiendung an:" default answer the prefix_or_suffix buttons {"Cancel", "Ok"} default button 2
    copy the result as list to {the prefix_or_suffix, the button_pressed}
    if the prefix_or_suffix is not "" then exit repeat
end repeat


set the item_list to list folder vorderseiten_folder without invisibles
set source_folder to vorderseiten_folder as string
repeat with i from 1 to number of items in the item_list
    set this_item to item i of the item_list
    set this_item to (source_folder & this_item) as alias
    set this_info to info for this_item
    set the current_name to the name of this_info
    if folder of this_info is false and ¬
        alias of this_info is false then
        if the button_pressed is "Ok" then
            set the new_file_name to the ((10000 + i) & "a" & (the prefix_or_suffix)) as string
        end if
        my set_item_name(this_item, the new_file_name, ziel_folder, current_name)
    end if
end repeat

set the item_list to list folder rueckseiten_folder without invisibles
set source_folder to rueckseiten_folder as string
repeat with i from 1 to number of items in the item_list
    set this_item to item ((number of items in the item_list) - i + 1) of the item_list
    set this_item to (source_folder & this_item) as alias
    set this_info to info for this_item
    set the current_name to the name of this_info
    if folder of this_info is false and ¬
        alias of this_info is false then
        if the button_pressed is "Ok" then
            set the new_file_name to the ((10000 + i) & "b" & (the prefix_or_suffix)) as string
        end if
        my set_item_name(this_item, the new_file_name, ziel_folder, current_name)
    end if
end repeat


beep 2

on set_item_name(this_item, new_item_name, ziel_ordner, alter_name)
    tell application "Finder"
        --activate
        set the parent_container_path to (the container of this_item) as text
        set the ziel_ordner_pfad to ziel_ordner as text
        if not (exists item (the ziel_ordner_pfad & new_item_name)) then
            try
                duplicate file this_item to (ziel_ordner) with replacing
                set that_item to ((the ziel_ordner & alter_name) as text) as alias
                set the name of that_item to (new_item_name)
            on error the error_message number the error_number
                if the error_number is -59 then
                    set the error_message to "This name contains improper characters, such as a colon (:)."
                else --the suggested name is too long
                    set the error_message to error_message -- "The name is more than 31 characters long."
                end if
                --beep
                tell me to display dialog the error_message default answer new_item_name buttons {"Cancel", "Skip", "OK"} default button 3
                copy the result as list to {new_item_name, button_pressed}
                if the button_pressed is "Skip" then return 0
            end try
        end if
    end tell
end set_item_name

Dies speichert man im Scripteditor ab, und lässt es danach laufen.
Das Skript fragt zuerst nach dem Ordner indem die Vorderseiten liegen, danach nach dem Ordner wo die Rückseiten liegen, daraufhin nach dem Zielordner indem die Dateien sortiert kopiert werden sollen, und zu letzt nach der Dateiendung (z.B. .gif, oder .tiff).
Danach kopiert es die Dateien in den Zielordner in der richtigen Reihenfolge, also die erste Datei aus dem Vorderseitenordner und die letzte Seite aus dem Rückseitenordner immer zusammen. Die Dateien sind durchnummeriert, wobei die Vorderseiten immer auf a (plus Dateiendung) enden, und die Rückseiten auf b enden.

Umwandlung in PDF

Wem es ausreicht die Bilddateien sortiert auf dem Rechner zu haben, der ist an dieser Stelle fertig.
Um ein PDF zu erzeugen kann man für kleinere kleinere Aufgaben (bis etwa 1,5 GB Bilddaten) (neben anderen Programmen) das kostenlose Programm PDFLab nutzen. Man fügt die Bilder einfach per Drag&Drop des Ordners mit den sortierten Bildern in das Fenster von PDFLab ein. Nachdem alle Dateien dort aufgelistet sind (das kann ein wenig dauern wenn die Bilder größer sind) klickt man auf den „Create PDF“ Button in der Menüleiste, und lässt das PDFLab einige Zeit lang arbeiten.

Wenn PDFLab fertig ist, fragt es wohin das PDF gespeichert werden soll.
Die entstandene PDF-Datei kann man sich nun ansehen, oder archivieren. Falls einem noch die Dateigröße des PDFs zu hoch ist, empfiehlt es sich das PDF mit dem Programm Vorschau zu öffnen, dann den Druckdialog öffnen, und unter den ColorSync-Optionen ein eigenes Profil auswählen/Anlegen, welches die Bilder als JPEG komprimiert mit mittlerer oder niedriger Qualität, und je nach der Auflösung des Scans auch evtl. die Bildgröße reduziert. Wenn man nun „Als PDF sichern“ wählt, so erhält man nach kurzer Wartezeit ein neues PDF, welches, wenn man die Optionen passend gesetzt hat, einen guten Kompromiss aus Dateigröße und Qualität bieten sollte.

Dieser Beitrag wurde unter Mac, Technik veröffentlicht. Setze ein Lesezeichen auf den Permalink.

1 Response to Bequem umfangreiche doppelseitige Papiervorlagen in PDF umwandeln

  1. Pingback: Johannes Formanns Webseite

Kommentare sind geschlossen.